# Analysis II Darstellungen 

Mathematik in wxMaxima www.mathematik-verstehen.de Haftendorn Dez 2010

### Handling

Achtung: Durch Anklicken der linken Zellmarkierung kann man die 
Abschnitte und auch einzelne Zellen aufklappen und auch wieder zuklappen.

Endung *.wxmx ist komfortabel. Ist die Endung *.wxm muss man 
erst noch alle Ausgaben neu erzeugen. Mit Strg r  werden alle aufgeklappten Zellen ausgewertet.
Zum Lernen ist es besser die Zellen einzeln (mit Shift+Enter) auszuwerten.

Werte einzelne Zellen aus mit Shift-Enter. 
Auswertung in einem Rutsch: Falte alle Abschnitte auf,
werte alle Zellen mit Strg r aus ( auch Menu Cell Alle Zellen auswerten).

### Inhalt

1 Parameterdarstellungen 
2 Polarkoordinaten
3 Implizite Darstellungen 

## Parameterdarstellungen

### Darstellung in wxplot 

wxplot2d([ ['parametric, 5*cos(t), 2*sin(t), [t, 0, 6], [nticks, 300]]], [x,-5,5])$

wxplot2d([ ['parametric, t*cos(t), t*sin(t), [t, 0, 2*%pi], [nticks, 300]]], [x,-5,6.5])$

### Dartellung in Maxima mit gnuplot

Erklärungen zum Gebrauch bei Datei "Sinustorte" in Analysis 3d.
Diese Methode halte ich für flexibler, da die Möglichkeiten
von wxplot doch sehr begrenzt erscheinen. Zumindest erhält man
Hilfen nur zu dieser ausführlicheren Version. 

load(draw)$
kurven:gr2d(nticks=500,line_width=3,color=red,
                 parametric(t*cos(t), t*sin(t), t, 0, 2*%pi) , color=blue,
                 parametric(log(t)*cos(t), log(t)*sin(t), t, 0.1, 30*%pi)  )$
parabel:gr2d(line_width=3,color=green,
                 parametric(t, t^2, t, -2,2))$

draw(kurven)$

Die Logik ist: Das Package draw wird geladen. Darin sind viele
nützliche Befehle. Mit ihnen erzeugt man mit gr2d() und gr3d()
Grafikobjekte, die dann von draw(....) dargestellt werden. 
Was in ein gemeinsames Bild soll, muss in demselben Grafikobjekt
stehen. Bekommt draw mehrere Objekte, werden sie untereinander
dargestellt.

draw(kurven,parabel)$

## Polarkoordinaten 

### ungünstige Version 

Im Menu Plotten bei Optionen "setpolar" wählen

wxplot2d([phi*phi], [phi,0,2*%pi],[x,-15,9],[y,-25,5],
 [gnuplot_preamble, "set polar; set zeroaxis;"])$

Diese Darstellung ist absolut unbefriedigend, denn es wird längst 
nicht alles dargestellt.Der Graph müsste einmal herum gehen.

### Günstige Version mit draw2d

load(draw)$

draw2d(user_preamble = "set grid polar",
             nticks = 300, xrange = [-15,40], yrange = [-25,5],
             color = blue, line_width = 3,             
             polar(ph,ph,0,2*%pi) )$

draw2d(user_preamble = "set grid polar",
             nticks = 200, xrange = [-5,5], yrange = [-5,5],
             color = blue, line_width = 3,
             polar(10/theta,theta,1,10*%pi) ,
             color = red, line_width = 3,             
             polar(log(ph),ph,1,2*%pi) 
)$

Hier hat man wesentlich mehr Möglichkeiten. 

### Version mit Grafikobjekten

spira:gr2d(user_preamble = "set grid polar",
             nticks = 200, xrange = [-5,5], yrange = [-5,5],
  color = blue, line_width = 3,
             title = "Hyperbolic Spiral",
             polar(10/theta,theta,1,10*%pi) )$
draw(spira)$

Diese Version erlaubt die größte Flexibilität.
Insbesondere kann man mehrere Darstellungen in 
ein Grafikobjekt schreiben.

loga:gr2d(user_preamble = "set grid polar",
             nticks = 200, xrange = [-5,5], yrange = [-5,5],
             color = blue, line_width = 3,
             title = "logarithmische Spirale",
             polar(log(theta),theta,0.01,20*%pi) ,
             color = red, line_width = 3,
             parametric(t,tan(1)*t,t,-2,2)
 )$
draw(loga)$

## Implizite Darstellungen

### Implizit 2D

load(draw)$

draw(gr2d(line_width=3, color=red,grid=true,
             implicit(y^2=x^3-2*x+1, x, -2,4, y, -4,4)
            ))$

### Implizit 3D und Parameterkurven 3D

elli:gr3d(enhanced3d=true,implicit((x^2)/16+(y^2)/9+(z^2)/9=1,
              x,-4,4,y,-3,3,z,-3,3))$ 
draw(elli)$

draw(gr3d(enhanced3d=false,x_voxel=15, y_voxel=15, z_voxel=15,
                 implicit( 1/4*y^2 +1/4* z^2=1, x, -3, 3,y, -2, 2,z,-2,2),
                 enhanced3d=true,
                 implicit(1/9*x^2 +1/4*y^2 +1/4* z^2=1, x, -3, 3,y, -2, 2,z,-2,2),
                 enhanced3d=false, color=black, line_width=4,
                 parametric(3,2*cos(t),2*sin(t),t,0,2*%pi),
                 parametric(0,2*cos(t),2*sin(t),t,0,1*%pi),
                 parametric(-3,2*cos(t),2*sin(t),t,0,1*%pi)
                ) )$